extends SceneTree

const MainScene: PackedScene = preload("res://main/main.tscn")
const TEST_PORT: int = 18194
const LATE_MESSAGE: String = "late join visibility check"


func _initialize() -> void:
	call_deferred("_run")


func _run() -> void:
	var arguments: PackedStringArray = OS.get_cmdline_user_args()
	if arguments.has("host"):
		await _run_host()
	elif arguments.has("first"):
		await _run_first_client()
	elif arguments.has("late"):
		await _run_late_client()
	else:
		push_error("Late-join validation needs host, first, or late mode.")
		quit(1)


func _run_host() -> void:
	var main: Node = await _create_initialized_main()
	var session := main.get_node("%NetworkSession") as NetworkSession
	var save_manager := main.get("_save_manager") as PlayerSaveManager
	assert(session.start_private_host(TEST_PORT))
	assert(save_manager.initialize_new_game())
	main.call("_enter_gameplay")
	for _frame: int in 4:
		await physics_frame
	assert(session.set_host_open(true))
	assert(await _wait_for_registry_size(session, 3))
	var spawn := main.get_node("%PlayerSpawnService") as PlayerSpawnService
	assert(spawn.get_peer_ids().size() == 3)
	await create_timer(5.0).timeout
	print("Late-join multiplayer host validation: PASS")
	await _cleanup(main, session)


func _run_first_client() -> void:
	var main: Node = await _create_initialized_main()
	var session := await _join(main)
	var profile := main.get_node("%NetworkProfileService") as NetworkProfileService
	var preview: Dictionary = profile.get_persisted_appearance().duplicate(true)
	preview["scale"] = 0.9
	assert(profile.preview_appearance(preview))
	await create_timer(2.0).timeout
	var chat := main.get_node("%NetworkChatService") as NetworkChatService
	var deadline: int = Time.get_ticks_msec() + 15000
	while Time.get_ticks_msec() < deadline:
		await process_frame
		if (
			session.get_authenticated_peer_ids().size() == 3
			and _history_contains(chat, LATE_MESSAGE)
		):
			break
	assert(session.get_authenticated_peer_ids().size() == 3)
	assert(_history_contains(chat, LATE_MESSAGE))
	var spawn := main.get_node("%PlayerSpawnService") as PlayerSpawnService
	assert(spawn.get_peer_ids().size() == 3)
	print("Late-join first-client validation: PASS")
	await _cleanup(main, session)


func _run_late_client() -> void:
	var main: Node = await _create_initialized_main()
	var session := await _join(main)
	var deadline: int = Time.get_ticks_msec() + 8000
	while (
		Time.get_ticks_msec() < deadline
		and session.get_authenticated_peer_ids().size() < 3
	):
		await process_frame
	assert(session.get_authenticated_peer_ids().size() == 3)
	var spawn := main.get_node("%PlayerSpawnService") as PlayerSpawnService
	assert(spawn.get_peer_ids().size() == 3)
	var chat := main.get_node("%NetworkChatService") as NetworkChatService
	assert(chat.send_local_message(LATE_MESSAGE))
	await create_timer(1.0).timeout
	print("Late-join late-client validation: PASS")
	await _cleanup(main, session)


func _join(main: Node) -> NetworkSession:
	main.call("_on_title_join_game_requested", "127.0.0.1:%d" % TEST_PORT)
	var session := main.get_node("%NetworkSession") as NetworkSession
	var deadline: int = Time.get_ticks_msec() + 20000
	while Time.get_ticks_msec() < deadline:
		await process_frame
		if session.state == NetworkSession.State.VERIFYING_SERVER_IDENTITY:
			main.call("_confirm_server_trust")
		if session.is_joined_client() and bool(main.get("_gameplay_started")):
			return session
	assert(false, "Client did not join in time.")
	return session


func _wait_for_registry_size(session: NetworkSession, expected: int) -> bool:
	var deadline: int = Time.get_ticks_msec() + 25000
	while Time.get_ticks_msec() < deadline:
		await process_frame
		if session.get_authenticated_peer_ids().size() == expected:
			return true
	return false


func _history_contains(service: NetworkChatService, body: String) -> bool:
	return service.get_history().any(
		func(message: Dictionary) -> bool:
			return str(message.get("body", "")) == body
	)


func _create_initialized_main() -> Node:
	root.size = Vector2i(1280, 720)
	var main: Node = MainScene.instantiate()
	root.add_child(main)
	for _frame: int in 4:
		await process_frame
	if not bool(main.get("_application_initialized")):
		main.call("_activate_selected_data_path", "", true)
	for _frame: int in 8:
		await process_frame
	assert(bool(main.get("_application_initialized")))
	return main


func _cleanup(main: Node, session: NetworkSession) -> void:
	session.disconnect_session("")
	main.queue_free()
	for _frame: int in 4:
		await process_frame
	await create_timer(0.1).timeout
	quit()